AccessからVBAでメールを送信する２つの方法

Option Compare Database
Option Explicit
'------------------------------------------------------------
'   処理内容:アウトルックを起動
'   引数:なし
'   戻り値:なし
'　 更新：
'------------------------------------------------------------
'アウトルックを起動
Public Sub MailOpen()
  Dim ret   As Long
  
  'Outlookの起動
  ret = Shell("outlook", vbNormalFocus)
  If ret = 0 Then MsgBox "起動に失敗しました", vbOKOnly + vbCritical, "MailOpen()"
End Sub

'------------------------------------------------------------
'   処理内容:outlookでメール送信
'   引数:strTo(宛先),strTitle(件名),strDetail(本文)
'   戻り値:なし
'　 更新：
'------------------------------------------------------------
Public Sub MailSend(strTo, strTitle, strDetail)
    Dim myApp   As Outlook.Application
    Dim myMail  As Outlook.MailItem
    
    'outlookのｵﾌﾞｼﾞｪｸﾄ作成
    Set myApp = CreateObject("Outlook.Application")
    Set myMail = myApp.CreateItem(ItemType:=olMailItem)

    '引数の宛先・件名・本文ｾｯﾄ
    With myMail
        .To = strTo
        .subject = strTitle
        .Body = strDetail
        '重要度設定をﾉｰﾏﾙにする
        .Importance = olImportanceNormal
    End With
        
    'ｴﾗｰ時続行
    On Error Resume Next
    myMail.send
    On Error GoTo 0

    'ｵﾌﾞｼﾞｪｸﾄｸﾘｱ
    Set myMail = Nothing
    Set myApp = Nothing
End Sub

‘メールを送信する
Private Sub cmb送信_Click()

Call MailOpen
Call MailSend(Me.txt宛先, Me.txt件名, Me.txt本文)　’ﾌｫｰﾑ上の値を引数渡し

End Sub

'------------------------------------------------------------
'   処理内容:CDOメール送信
'   引数:なし
'   戻り値:True/False
'------------------------------------------------------------
Public Function cdoSendMail() As Boolean

    Dim objCDO
    Dim MSgw
    
    On Error GoTo Err_Exit
    
    '戻り値の初期化
    cdoSendMail = False
      
    Set objCDO = CreateObject("CDO.Message")
    
    'CDOのスキーマを定義
    MSgw = "http://schemas.microsoft.com/cdo/configuration/"
    
    With objCDO.Configuration.Fields
        'メール送信方法
        .Item(MSgw & "sendusing") = 2
        'SMTPサーバーのアドレス
        .Item(MSgw & "smtpserver") = "xxxx.xxxxx.jp"
        'SMTPサーバーのポート
        .Item(MSgw & "smtpserverport") = 465
        '差出人ユーザー名
        .Item(MSgw & "sendusername") = "xxx@xxx.com"
        '認証コード
        .Item(MSgw & "sendpassword") = "xxxxx"
        'SSL認証要
        .Item(MSgw & "smtpusessl") = True
        '認証方式(1)
        .Item(MSgw & "smtpauthenticate") = cdoBasic
        'タイムアウト
        .Item(MSgw & "smtpconnectiontimeout") = 60
        .Update
    End With
     
    '差出人メールアドレス
    objCDO.From = Me.txt差出人
    
    'あて先メールアドレス
    objCDO.To = Me.txt宛先
    
    'CCメールアドレス
    objCDO.CC = Me.txtCC
    
    '件名
    objCDO.subject = Me.txt件名
    '本文
    objCDO.textBody = Me.txt本文
    
    '文字化け対応のため追加
    objCDO.TextBodyPart.Charset = "ISO-2022-JP"
     
    objCDO.send
    
    MsgBox "メールを送信しました。", vbOKOnly + vbInformation, "送信完了"
    
    '正常終了
    cdoSendMail = True
    
    Exit Function
    
Err_Exit:
    MsgBox Err.Number & ":" & Err.Description, vbOKOnly + vbCritical, "cdoSendMail()"
       
End Function