VBAで2点間（緯度経度）の距離を求める方法

Option Compare Database
Option Explicit

Const GRS80_A = 6378137#
Const GRS80_E2 = 6.69438002301188E-03
Const GRS80_MNUM = 6335439.32708317
 
Const PAI = 3.14159265358979
 
Function deg2rad(deg As Double) As Double
 
    deg2rad = deg * PAI / 180#
 
End Function

'***********************************************************************
'　[説　明]　2地点間の直線距離を求める関数
'　[引　数]　lat1:地点1緯度　lng1:地点1経度　lat2:地点2緯度　lng2:地点2経度
'　[戻り値]　なし
'***********************************************************************
Public Sub calcHubeny(lat1 As Double, lng1 As Double, lat2 As Double, lng2 As Double)
 
    Dim my As Double
    Dim dy As Double
    Dim dx As Double
    Dim sin As Double
    Dim w As Double
    Dim m As Double
    Dim n As Double
    Dim dym As Double
    Dim dxncos As Double
     
    my = deg2rad((lat1 + lat2) / 2#)
    dy = deg2rad(lat1 - lat2)
    dx = deg2rad(lng1 - lng2)
     
    sin = Math.sin(my)
    w = Math.Sqr(1# - GRS80_E2 * sin * sin)
    m = GRS80_MNUM / (w * w * w)
    n = GRS80_A / w
     
    dym = dy * m
    dxncos = dx * n * Math.Cos(my)
     
    'メートルで取得するので、キロメートルに変換し小数第一位までにする
    MsgBox "距離：" & Round(Math.Sqr(dym * dym + dxncos * dxncos) / 1000, 1) & "km", vbInformation, "直線距離は・・・"
 
End Sub

'***********************************************************************
'　[説　明]　2点間の道路距離を求める
'　[引　数]　lat1:地点1緯度　lng1:地点1経度　lat2:地点2緯度　lng2:地点2経度
'　[戻り値]　getCoordinate(0):緯度　getCoordinate(1):経度
'***********************************************************************
Public Sub getGoogledistance(lat1 As Double, lng1 As Double, lat2 As Double, lng2 As Double)

    Dim HTTP        As Object
    
    Set HTTP = CreateObject("MSXML2.XMLHTTP")
    
    HTTP.Open "GET", "https://maps.googleapis.com/maps/api/distancematrix/xml?" & _
        "origins=" & lat1 & "," & lng1 & _
        "&destinations=" & lat2 & "," & lng2 & _
        "&avoid=highways", False
    HTTP.send
    
    Do While HTTP.ReadyState <> 4
        DoEvents
    Loop
    
    MsgBox "時間：" & _
           HTTP.responseXML.DocumentElement.LastChild.LastChild.ChildNodes(1).LastChild.nodeTypedValue & vbLf & _
           "距離：" & _
           HTTP.responseXML.DocumentElement.LastChild.LastChild.ChildNodes(2).LastChild.nodeTypedValue, vbInformation, "道路距離は・・・"
    Set HTTP = Nothing
    
 End Sub