スパイラルに作成したテーブルにACCESS VBAからデータを追加・削除する方法

' *==============================================================
' * Databaseﾃﾞｰﾀ削除用のJsonテキスト作成処理
' *
' * @param strjson 作成したJsonテキスト
' * @return True/False
' *==============================================================
Public Function MakeDelJson(ByRef strjson As String) As Boolean
    
    Dim param           As New Dictionary
    Dim strsignature    As String
    Dim intPass         As Long
    
    
    On Error GoTo Err_Exit
    
    '戻り値の初期化
    MakeDelJson = False
    
    intPass = DateDiff("s", #1/1/1970 9:00:00 AM#, Now)
    strsignature = HmacSha1(csToken & "&" & CStr(intPass), csSecret)
    
    'dbﾀｲﾄﾙを連想配列にセット
    param.Add "spiral_api_token", csToken
    param.Add "passkey", intPass
    param.Add "signature", strsignature
    param.Add "db_title", csMailTable
    
    '連想配列からJSONフォーマットに変換
    strjson = ConvertToJson(param)
        
    Debug.Print strjson
    MakeDelJson = True
    
    Exit Function
    
Err_Exit:
    MsgBox Err.Number & ":" & Err.Description, vbOKOnly + vbCritical
 
End Function

'------------------------------------------------------------
'   処理内容:SPIRAL APIを利用してﾒｰﾙ送信
'   引数:
'   戻り値:なし
'------------------------------------------------------------
Private Sub funcApiMailSend()
    Dim ret         As String
    Dim strjson     As String
    Dim parse       As Object
    Dim wkTitle     As String
    
    DoCmd.Hourglass True
  
    'ｽﾊﾟｲﾗﾙへのﾃﾞｰﾀｾｯﾄ(delete)
    If MakeDelJson(strjson) = False Then
        MsgBox "Json文字列作成に失敗しました。再度手続きをお願いします。"
        Exit Sub
    Else
        Dim ret As String
        'APIｺｰﾙ
        ret = CallSpiralApi(strjson, "database/delete/request")
        
        'APIからの戻りﾃｷｽﾄ(JSON）を扱いやすいobjectに変換
        Set parse = JsonConverter.ParseJson(ret)
        
        If parse("code") = 0 Then
            'MsgBox "削除しました", vbOKOnly + vbInformation
        Else
            MsgBox ret, vbOKOnly + vbCritical
        End If
    End If
    
    'ｽﾊﾟｲﾗﾙへのﾃﾞｰﾀｾｯﾄ(insert)
    '***ｺｰﾄﾞ省略***
    
    'ｽﾊﾟｲﾗﾙからのﾒｰﾙ送信
    '***ｺｰﾄﾞ省略***
    
    DoCmd.Hourglass False

        
End Sub

' *==============================================================
' * SPIRALのAPI関数コール
' *
' * @param request POST/GET
' * @param url
' * @param accesstken(Encodeが必要であればEncode済みの文字列）
' * @param param（jsonオブジェクト）
' * @return responseテキストデータ
' *==============================================================
Public Function CallSpiralApi(ByVal param As String, ByVal request_kind As String) As String

    On Error GoTo Err_Exit
    
    With CreateObject("MSXML2.XMLHTTP")
        .Open "POST", "https://reg18.smp.ne.jp/api/service", False
        
        'Basic認証
        .setRequestHeader "X-SPIRAL-API", request_kind
        .setRequestHeader "Content-Type", "application/json; charset=UTF-8"
        .send param
        
        '結果が戻るまで待機
        Do While .readyState < 4
            DoEvents
        Loop

        'デバッグは↓をアンコメントしてレスポンスを確認
        Debug.Print .responseText
        
        '.responseTextを戻り値とする
        CallSpiralApi = .responseText
        
    End With
    
    Exit Function
    
    
Err_Exit:
    MsgBox Err.Number & ":" & Err.Description, vbOKOnly + vbCritical
   
    
End Function

' *==============================================================
' * Databaseﾚｺｰﾄﾞ追加用のJsonテキスト作成処理
' *
' * @param strjson 作成したJsonテキスト, testflag
' * @return True/False
' *==============================================================
Public Function MakeInsJson(ByRef strjson As String, testflag As Boolean) As Boolean
    
    Dim param           As New Dictionary
    Dim strsignature    As String
    Dim newObj          As New Dictionary
    Dim dataObj         As New Dictionary
    Dim intPass         As Long
    
    On Error GoTo Err_Exit
    
    '戻り値の初期化
    MakeInsJson = False
    
    intPass = DateDiff("s", #1/1/1970 9:00:00 AM#, Now)
    strsignature = HmacSha1(csToken & "&" & CStr(intPass), csSecret)
    
    '追加したいデータを連想配列にセット
    param.Add "spiral_api_token", csToken
    param.Add "passkey", intPass
    param.Add "signature", strsignature
    param.Add "db_title", csMailTable
    param.Add "columns", Array("f002546638", "f002546639", "f002546640", "f002546641", "f002546642")
    param.Add "data", New Collection
    
    param("data").Add Array("hoge1@xxxxx.jp", "サンプル1", "2020/09/30", "備考1", "124", "12300")
    param("data").Add Array("hokge2@xxxxx.jp", "サンプル2", "2020/09/30", "備考2", "125", "11500")

    '連想配列からJSONフォーマットに変換
    strjson = ConvertToJson(param)
    
    Call makeText(strjson)
    MakeInsJson = True
    
    Exit Function
    
Err_Exit:
    MsgBox Err.Number & ":" & Err.Description, vbOKOnly + vbCritical
 
End Function